Using the IntervalTools package to validate Lemma 3.4 from Counting Zeros of L-Functions.

<<IntervalTools`

In “Counting Zeros of Dirichlet L-Functions”, we define a function E(a,d,T) arising from using Stirling’s Formula to bound  the change in the LogGamma function. It is convenient to code in the following terms.  The domain is a∈{0,1}, 0≤d≤(9/2), T≥5/7. In the code in this notebook, we refer to E in paper as GammaSpread in code.

In the paper, Lemma 3.4 asserts that E(a,d,T) is an increasing function of d, and for (1/4)≤d≤(5/8) is bounded by
	((E(a,d,T))/π)≤(((640+216a)-112-39a)/(1536(3T+3a-1)))+(1/(2^10)).

Defining GammaSpread

e1[a_,d_,T_]=(4 (4+3 π))/(45 ((((((17+2 a))^2)+4 (T^2)))^(3/2)))+(8+6 π)/(45 ((((((17+2 a-2 d))^2)+4 (T^2)))^(3/2)))+(8+6 π)/(45 ((((((17+2 a+2 d))^2)+4 (T^2)))^(3/2)));
e2[a_,d_,T_]=-((4 T)/(3 ((((17+2 a))^2)+4 (T^2))))+(2 T)/(3 ((((17+2 a-2 d))^2)+4 (T^2)))+(2 T)/(3 ((((17+2 a+2 d))^2)+4 (T^2)))+(1/12696)(((d^2)(T+94+39a))/((T^2)+(((17+2a))^2)));
e3[a_,d_,T_]=(T/2) Log[1+(((17+2 a))^2)/(4 (T^2))]-(T/4)Log[1+(((17+2 a-2 d))^2)/(4 (T^2))]-(T/4)Log[1+(((17+2 a+2 d))^2)/(4 (T^2))]+(1/2)(((d^2)(T+94+39a))/((T^2)+(((17+2a))^2)));
e4[shift_,a_,d_,T_]=2 ArcTan[(shift+2 a)/(2 T)]-ArcTan[(shift+2 a-2 d)/(2 T)]-ArcTan[(shift+2 a+2 d)/(2 T)];
e5[a_,d_,T_]=(1/4) (15+2 a-2 d) ArcTan[(17+2 a-2 d)/(2 T)]+(1/4) (15+2 a+2 d) ArcTan[(17+2 a+2 d)/(2 T)]-(1/2) (15+2 a) ArcTan[(17+2 a)/(2 T)]-(1/2+1/12696)(((d^2)(T+94+39a))/((T^2)+(((17+2a))^2)));

GammaSpread[a_,d_,T_]:=e1[a,d,T]+e2[a,d,T]+e3[a,d,T]+e4[1,a,d,T]+e4[5,a,d,T]+e4[9,a,d,T]+e4[13,a ,d,T]+e5[a,d,T];
GammaSpread[a,d,T]

Note  that e2, e3, and e5 have terms that cancel. They are included to make nicer interval enclosures.

We need to prove that E(a,d,T) is a monotone increasing function of  d, is positive for the entire domain, and is monotone decreasing in T.

GammaSpread[a,d,T] is increasing in d

That is, the derivative with respect to d is positive. This takes quite a bit of work.

D[GammaSpread[a,d,T],d]

We will benefit from introducing a normalizing factor.

Limit[T*D[GammaSpread[a,d,T],d],T->∞]

Thus, it is helpful to work with T*D[GammaSpread[a,d,T],d] instead of the unadorned derivative. We need to demonstrate that the following quantity is nonnegative. We  also make the substitution 4(T^2)->1/t, so that the behavior at T->∞ is laid bare. Note: 0≤t≤(1/(4(((5/7))^2)))=(49/100).

T*D[GammaSpread[a,d,T],d]/.T->(1/(2Sqrt[t]))

Before proceeding further, we rearrange the expression considerably. Aside from carefully chosen algebra, we use http://fungrim.org/entry/503d4d/
	 ArcTan[u]-ArcTan[v]==ArcTan[((u-v)/(1+u v))] , valid for u v>-1.
In  our case, u=(17+2a+2d)(Sqrt[t]) and v=(17+2a-2d)(Sqrt[t]), so that u v >-1  for a ∈{0,1}, t≥0, and 0≤d≤2. The identity becomes
	ArcTan[(17+2 a+2 d) (Sqrt[t])]-ArcTan[(17+2 a-2 d) (Sqrt[t])] == ArcTan[(((17+2 a+2 d) (Sqrt[t])-(17+2 a-2 d) (Sqrt[t]))/(1+(17+2 a+2 d) (Sqrt[t])(17+2 a-2 d) (Sqrt[t])))]==ArcTan[((4 d)/((1/(Sqrt[t]))+((((17+2 a))^2)-4 (d^2))(Sqrt[t])))]

FullSimplify[FullSimplify[List@@Expand[T*D[GammaSpread[a,d,T],d]/.T->(1/(2Sqrt[t]))]]//.{x___,b_,c___,y_,e___}/;Simplify`SimplifyCount[b/.a->1]+Simplify`SimplifyCount[y/.a->1]>Simplify`SimplifyCount[Together[b+y/.a->1]]:>{x,c,e,Simplify[Together[b+y]]}]

edGS1[a_,d_,t_]=Plus@@{(1/(1+(((1+2 a-2 d))^2) t)),(1/(1+(((5+2 a-2 d))^2) t)),(1/(1+(((9+2 a-2 d))^2) t)),(1/(1+(((13+2 a-2 d))^2) t)),-(1/(1+(((1+2 a+2 d))^2) t)),-(1/(1+(((5+2 a+2 d))^2) t)),-(1/(1+(((9+2 a+2 d))^2) t)),-(1/(1+(((13+2 a+2 d))^2) t)),FullSimplify[Together[((2 (17+2 a-2 d) t)/(3 (((1+(((17+2 a-2 d))^2) t))^2)))+(1/(2+2 (((17+2 a-2 d))^2) t))]],FullSimplify[Together[-((2 (17+2 a+2 d) t)/(3 (((1+(((17+2 a+2 d))^2) t))^2)))-(1/(2+2 (((17+2 a+2 d))^2) t))]]};
edGS1[a_,d_,0]=Limit[edGS1[a,d,t],t->0,Direction->"FromAbove"]; (* happens to be 0, no limit needed*)
edGS2[a_,d_,t_]=(1/(4 (Sqrt[t])))ArcTan[((4 d)/((1/(Sqrt[t]))+((((17+2 a))^2)-4 (d^2))(Sqrt[t])))];
edGS2[a_,d_,0]=Limit[edGS2[a,d,t],t->0,Direction->"FromAbove"]; (* happens to be d *)
edGS3[a_,d_,t_]=((2(4+3π)(t^2))/15)((((17+2 a-2 d))/((((((17+2 a-2 d))^2)t+1))^(5/2)))-(((17+2 a+2 d))/(((((((17+2 a+2 d))^2)t+1))^(5/2)) )));
edGS3[a_,d_,0]=Limit[edGS3[a,d,t],t->0,Direction->"FromAbove"]; (* happens to be 0, no limit needed*)
dGS[a_,d_,t_]:=edGS1[a,d,t]+edGS2[a,d,t]+edGS3[a,d,t];

It will be helpful to immediately  define  a  simple interval enclosure for  edGS2,  as the natural  enclosure is badly behaved at t=0.

edGS2[a_,d_Interval,t_Interval]:=Interval[{Min[((d π)/(π+8 d (Sqrt[t])+((((17+2 a))^2)-4 (d^2)) π t))],Max[((d (π^2))/(4 (1+2 d π (Sqrt[t])+(((17+2 a))^2) t-4 (d^2) t)))]}];(* a lower bound from http://fungrim.org/entry/3fe47b/ *)
(* an upper bound from http://fungrim.org/entry/efebb8/ *)

Focus on a=1

For a=1, this function just isn’t convex enough to quickly go negative. We  consider fixed t, and expand in terms of d. Specifically, we have the following coefficients in a Taylor expansion of dGS[1,d,t] about d=0. The thought is that

dGS[1,d,t]=dGS[1,0,t]+(D[dGS[1,d,t],d]/.d->0)*d+(D[dGS[1,d,t],{d,2}]/.d->0)*((d^2)/2)+(D[dGS[1,d,t],{d,3}]/.d->ξ)*((d^3)/(3!))+

for some ξ between 0 and d.

coeffs[1]=With[{a=1},
{Limit[dGS[a,d,t],d->0],
Simplify[Limit[D[dGS[a,d,t],d],d->0]],Limit[D[dGS[a,d,t],{d,2}],d->0],
term3step1=D[dGS[a,d,t],{d,3}]}]

The first and third coefficients are 0, and, well, that last one is pretty messy.

We now use MooreSkelboe to bound the 2nd coefficient.

{bounds1,where1}=MooreSkelboeMinimize[t|->Evaluate[coeffs[1][[2]]],t|->Evaluate[coeffs[1][[2]]],{Interval[{0,49/100}]},1/(2^22)]
{N[bounds1,10],N[where1,10]}

We now use MooreSkelboe, after cleaning up  the expression  some, to bound the 4th coefficient.

term3step2=Map[Numerator[#]/FullSimplify[Denominator[#]]&,List@@Expand[term3step1]];

term3step3=term3step2//.{x1___,x2_,x3___,x4_,x5___}/;(Denominator[x2]===Denominator[x4]):>{x1,x3,x5,(1/(Denominator[x2]))FullSimplify[Numerator[x2]+Numerator[x4],Assumptions->0≤t≤49/100&&0≤d≤2]};

term3func[d_,t_]=term3step3;
term3func[d_,0]:=Limit[term3func[d,t],t->0,Direction->"FromAbove"];{bounds3,where3}=MooreSkelboeMinimize[term3func,term3func,{Interval[{0,5/9}],Interval[{0,(49/100)}]},(1/128),certificate->False]

We now have a lower bound which depends only on d  and is positive for small d.

Reduce[0≤d≤5/9&&0+Min[bounds1]*d+0*((d^2)/2)+Min[bounds3]*((d^3)/3)≥0]

ProveNonNegative[dGS[1,#1,#2]&,dGS[1,#1,#2]&,{Interval[{5/9,9/2}],Interval[{0,49/100}]},certificate->False]

And now a=0.

coeffs[0]=With[{a=0},
{Limit[dGS[a,d,t],d->0],
Simplify[Limit[D[dGS[a,d,t],d],d->0]],Limit[D[dGS[a,d,t],{d,2}],d->0],
term3step1=D[dGS[a,d,t],{d,3}]}]

{bounds1,where1}=MooreSkelboeMinimize[t|->Evaluate[coeffs[0][[2]]],t|->Evaluate[coeffs[0][[2]]],{Interval[{0,49/100}]},1/(2^20),certificate->False]

term3step2=Map[Numerator[#]/FullSimplify[Denominator[#]]&,List@@Expand[term3step1]];

term3step3=term3step2//.{x1___,x2_,x3___,x4_,x5___}/;(Denominator[x2]===Denominator[x4]):>{x1,x3,x5,(1/(Denominator[x2]))FullSimplify[Numerator[x2]+Numerator[x4],Assumptions->0≤t≤49/100&&0≤d≤2]};

term3func[d_,t_]=term3step3;
term3func[d_,0]:=Limit[term3func[d,t],t->0,Direction->"FromAbove"];{bounds3,where3}=MooreSkelboeMinimize[term3func,term3func,{Interval[{0,2/5}],Interval[{0,(49/100)}]},(1/128),certificate->False]

Reduce[0≤d≤2/5&&0+Min[bounds1]*d+0*((d^2)/2)+Min[bounds3]*((d^3)/3)≥0]

ProveNonNegative[dGS[0,#1,#2]&,dGS[0,#1,#2]&,{Interval[{2/5,9/2}],Interval[{0,49/100}]},certificate->False]

GammaSpread[a,d,T] is positive

In the paper,  we quickly began ignoring the absolute value  bars around E(a,d,T). Here, we prove that is legitimate.

GammaSpread[a,0,T]//Together

See? Clearly positive for both a and  every T≥5/7. As we know  that  the derivative  (with respect to d) is positive, we have reached  the desired  conclusion: E(a,d,T) is always  positive.

A bound  for  (1/4)≤d≤(2/5): (1/π)GammaSpread[a,d,T]≤(((8+a))/15)((d^2)/(3T-1+2a))+(1/128)

As GammaSpread is monotone in d, we have an easy interval enclosure.

GammaSpread[a_,dint_Interval,T_]:=
Interval[{Min[GammaSpread[a,Min[dint],T]],Max[GammaSpread[a,Max[dint],T]]}];

Now considering T an interval. Actually, we set T=(1/(2t)), with t ∈ Interval[{0,(7/10)}]. Note that if some function is monotone in t, then it is monotone in T.

e1

Simplify[Expand[(((4+3π)(t^2))/15)(((4 )/(((((((17+2 a))^2)(t^2)+1))^(5/2)) ))+(2/( ((((((17+2 a-2 d))^2)(t^2)+1))^(5/2))))+(2/( ((((((17+2 a+2 d))^2)(t^2)+1))^(5/2)) )))]-D[e1[a,d,(1/(2t))],t],Assumptions->(a==0||a==1)&&(1/4)≤d≤(2/5)&&0≤t≤(7/10)]

(((4+3π)(t^2))/15)(((4 )/(((((((17+2 a))^2)(t^2)+1))^(5/2)) ))+(2/( ((((((17+2 a-2 d))^2)(t^2)+1))^(5/2))))+(2/( ((((((17+2 a+2 d))^2)(t^2)+1))^(5/2)) )))/.{a->0,d->Interval[{1/4,2/5}],t->Interval[{0,(7/10)}]}

(((4+3π)(t^2))/15)(((4 )/(((((((17+2 a))^2)(t^2)+1))^(5/2)) ))+(2/( ((((((17+2 a-2 d))^2)(t^2)+1))^(5/2))))+(2/( ((((((17+2 a+2 d))^2)(t^2)+1))^(5/2)) )))/.{a->1,d->Interval[{1/4,2/5}],t->Interval[{0,(7/10)}]}

Thus e1 is monotone in T

e1[a_,d_,Tint_Interval]:=Block[{T},MonotoneEnclosure[e1[a,d,T],T,Tint]];

e2

While e2 is not monotone in T, we can use its derivative as a montonicity test.

Simplify[D[e2[a,d,(1/(2t))],t]==(((d^2) (1+4 t (94+39 a-(((17+2 a))^2) t)))/(6348 (((1+4 (((17+2 a))^2) (t^2)))^2)))+(1/3) (-(4/(((1+(((17+2 a))^2) (t^2)))^2))+(2/(1+(((17+2 a))^2) (t^2)))+(2/(((1+(((17+2 a-2 d))^2) (t^2)))^2))-(1/(1+(((17+2 a-2 d))^2) (t^2)))+(2/(((1+(((17+2 a+2 d))^2) (t^2)))^2))-(1/(1+(((17+2 a+2 d))^2) (t^2)))),Assumptions->(a==0||a==1)&&(1/4)≤d≤(2/5)&&0≤t≤(7/10)]

e2[a_,d_,Tint_Interval]:=Module[{tint=(1/(2Tint)),deriv,crits,vals,ends,t,T},
deriv[t_]=(((d^2) (1+4 t (94+39 a-(((17+2 a))^2) t)))/(6348 (((1+4 (((17+2 a))^2) (t^2)))^2)))+(1/3) (-(4/(((1+(((17+2 a))^2) (t^2)))^2))+(2/(1+(((17+2 a))^2) (t^2)))+(2/(((1+(((17+2 a-2 d))^2) (t^2)))^2))-(1/(1+(((17+2 a-2 d))^2) (t^2)))+(2/(((1+(((17+2 a+2 d))^2) (t^2)))^2))-(1/(1+(((17+2 a+2 d))^2) (t^2))));
crits=t/.Solve[deriv[t]==0,t,Reals];
crits=Select[crits,IntervalMemberQ[tint,#]&];
ends={Limit[e2[a,d,T],T->Min[Tint],Direction->"FromAbove"],Limit[e2[a,d,T],T->Max[Tint],Direction->"FromBelow"]};
vals=Union[ends,Map[e2[a,d,(1/(2#))]&,crits]];
Interval[{Min[vals],Max[vals]}]];

e3

Simplify[e3[a,d,(1/(2t))]==(((d^2) t (1+188 t+78 a t))/(1+4 (((17+2 a))^2) (t^2)))+(1/(8t))Log[1+((8 (d^2) (t^2) (-1+((((17+2 a))^2)-2 (d^2)) (t^2)))/((1+(((17+2 a-2 d))^2) (t^2)) (1+(((17+2 a+2 d))^2) (t^2))))],Assumptions->(a==0||a==1)&&(1/4)≤d≤(2/5)&&0≤t≤(7/10)]

Not a lot to do, here. Just try plugging in, and also try easy bounds on logarithm!

I use Mathematica’s “Maximize” and “Minimize”,

e3[a_,d_,Tint_Interval]:=Module[{tint=(1/(2Tint)),t,estimate1,estimate2,outexpr,inexpr,outside,inside},
outexpr=(((d^2) t (1+188 t+78 a t))/(1+4 (((17+2 a))^2) (t^2)));
inexpr=((8 (d^2) (t^2) (-1+((((17+2 a))^2)-2 (d^2)) (t^2)))/((1+(((17+2 a-2 d))^2) (t^2)) (1+(((17+2 a+2 d))^2) (t^2))));
outside=PiecewiseMonotoneEnclosure[outexpr,t,t/.Solve[D[outexpr,t]==0,t,Reals],tint];
inside=PiecewiseMonotoneEnclosure[inexpr,t,t/.Solve[D[inexpr,t]==0,t,Reals],tint];
estimate1=outside+(1/(8t))Log[1+inside]/.t->tint;

(* note that it's just a function of 1 variable at this point *)
(* use (x/(1+x))≤ Log[1+x] ≤ x *)
outexpr=(((d^2) t (1+188 t+78 a t))/(1+4 (((17+2 a))^2) (t^2)))+(( (d^2) t (-1+((((17+2 a))^2)-2 (d^2)) (t^2)))/((1+(((17+2 a-2 d))^2) (t^2)) (1+(((17+2 a+2 d))^2) (t^2))));
outside=PiecewiseMonotoneEnclosure[outexpr,t,t/.Solve[D[outexpr,t]==0,t,Reals],tint];

inexpr=(((d^2) t (1+188 t+78 a t))/(1+4 (((17+2 a))^2) (t^2)))+(((d^2) t (-1+((((17+2 a))^2)-2 (d^2)) (t^2)))/(((1+(((17+2 a))^2) (t^2)))^2));
inside=PiecewiseMonotoneEnclosure[inexpr,t,t/.Solve[D[inexpr,t]==0,t,Reals],tint];

estimate2=Interval[{Min[inside],Max[outside]}];

(*estimate2=Block[{min,max},
max=First[Maximize[{(((d^2) t (1+188 t+78 a t))/(1+4 (((17+2 a))^2) (t^2)))+(( (d^2) t (-1+((((17+2 a))^2)-2 (d^2)) (t^2)))/((1+(((17+2 a-2 d))^2) (t^2)) (1+(((17+2 a+2 d))^2) (t^2)))),Min[tint]≤t≤Max[tint]},t,Reals]];
min=First[Minimize[{(((d^2) t (1+188 t+78 a t))/(1+4 (((17+2 a))^2) (t^2)))+(((d^2) t (-1+((((17+2 a))^2)-2 (d^2)) (t^2)))/(((1+(((17+2 a))^2) (t^2)))^2)),Min[tint]≤t≤Max[tint]},t,Reals]];
Interval[{min,max}]];*)

IntervalIntersection[estimate1,estimate2]];

e4

Fungrim entry 503d4d: ArcTan[x]-ArcTan[y]=ArcTan[((x-y)/(1+x y))], provided x,y are real and x y > -1.

Mathematica is not very good with this identity:

Union[Flatten[Table[Simplify[e4[s,a,d,(1/(2t))]==ArcTan[((8 (d^2) (2 a+s) (t^3))/(1+2 (2 (d^2)+(((2 a+s))^2)) (t^2)+(((2 a+s))^2) (2 a-2 d+s) (2 (a+d)+s) (t^4)))]],{a,0,1},{s,1,13,4},{d,1/4,2/5,1/100},{t,(1/100),7/10,1/100}]]]

e4[s_,a_,d_,Tint_Interval]:=
Module[{tint=(1/(2Tint)),inside,crits,vals,ends,t,T},
inside[t_]=((8 (d^2) (2 a+s) (t^3))/(1+2 (2 (d^2)+(((2 a+s))^2)) (t^2)+(((2 a+s))^2) (2 a-2 d+s) (2 (a+d)+s) (t^4)));
crits=t/.Solve[D[inside[t],t]==0,t,Reals];
crits=Select[crits,IntervalMemberQ[tint,#]&];
ends={Limit[e4[s,a,d,T],T->Min[Tint],Direction->"FromAbove"],Limit[e4[s,a,d,T],T->Max[Tint],Direction->"FromBelow"]};
vals=Union[ends,Map[ArcTan[inside[#]]&,crits]];
Interval[{Min[vals],Max[vals]}]];

e5

Simplify[D[e5[a,d,(1/(2t))],t]==-(((15+2 a) (17+2 a))/(2+2 (((17+2 a))^2) (t^2)))-((6349 (d^2) (1+2 (94+39 a) t))/(3174 (((1+4 (((17+2 a))^2) (t^2)))^2)))+((6349 (d^2))/(6348 (1+4 (((17+2 a))^2) (t^2))))+(((15+2 a-2 d) (17+2 a-2 d))/(4 (1+(((17+2 a-2 d))^2) (t^2))))+(((15+2 a+2 d) (17+2 a+2 d))/(4 (1+(((17+2 a+2 d))^2) (t^2)))),Assumptions->(a==0||a==1)&&(1/4)≤d≤(2/5)&&0≤t≤(7/10)]

e5[a_,d_,Tint_Interval]:=Module[{tint=(1/(2Tint)),deriv,crits,vals,ends,t,T},
deriv[t_]=-(((15+2 a) (17+2 a))/(2+2 (((17+2 a))^2) (t^2)))-((6349 (d^2) (1+2 (94+39 a) t))/(3174 (((1+4 (((17+2 a))^2) (t^2)))^2)))+((6349 (d^2))/(6348 (1+4 (((17+2 a))^2) (t^2))))+(((15+2 a-2 d) (17+2 a-2 d))/(4 (1+(((17+2 a-2 d))^2) (t^2))))+(((15+2 a+2 d) (17+2 a+2 d))/(4 (1+(((17+2 a+2 d))^2) (t^2))));
crits=t/.Solve[deriv[t]==0,t,Reals];
crits=Select[crits,IntervalMemberQ[tint,#]&];
ends={Limit[e5[a,d,T],T->Min[Tint],Direction->"FromAbove"],Limit[e5[a,d,T],T->Max[Tint],Direction->"FromBelow"]};
vals=Union[ends,Map[e5[a,d,(1/(2#))]&,crits]];
Interval[{Min[vals],Max[vals]}]];

The Bound in Lemma 3.4

(1/(3T-1+3a))(-(7/96)-((13 a)/512)+((5/12)+((9 a)/64)) d)==(((640+216a)d-112-39a)/(1536(3T+3a-1)))//Simplify

For each value of a, verification took about 20 minutes.

AbsoluteTiming[{fa,un,pr}=With[{a=0},ProveNonNegative[((1/(2^10))+(1/(3*#2-1+3a))(-(7/96)-((13 a)/512)+((5/12)+((9 a)/64)) #1)-((GammaSpread[a,#1,#2])/π))&,((1/(2^10))+(1/(3*#2-1+3a))(-(7/96)-((13 a)/512)+((5/12)+((9 a)/64)) #1)-((GammaSpread[a,#1,#2])/π))&,{Interval[{1/4,5/8}],Interval[{5/7,∞}]},MaxDepth->20]];]
Length/@{fa,un,pr}

AbsoluteTiming[{fa,un,pr}=With[{a=1},ProveNonNegative[((1/(2^10))+(1/(3*#2-1+3a))(-(7/96)-((13 a)/512)+((5/12)+((9 a)/64)) #1)-((GammaSpread[a,#1,#2])/π))&,((1/(2^10))+(1/(3*#2-1+3a))(-(7/96)-((13 a)/512)+((5/12)+((9 a)/64)) #1)-((GammaSpread[a,#1,#2])/π))&,{Interval[{1/4,5/8}],Interval[{5/7,∞}]},MaxDepth->20]];]
Length/@{fa,un,pr}

Manipulate[Plot[{(1/π)GammaSpread[a,d,T],(1/(2^10))+(1/(3T-1+3a))(-(7/96)-((13 a)/512)+((5/12)+((9 a)/64)) d)},{d,1/4,5/8},PlotRange->All,ImageSize->500,PlotLegends->{"actual","bound"}],{a,{0,1}},{T,5/7,10}]